FileExists() and FolderExists()

        8 votes: ****      36,452 views      0 comments
by Allen Browne, 30 June 2006    (Access 95+)

Microsoft Access: VBA Programming Code

Provided by Allen Browne, June 2006


FileExists() and FolderExists() functions

Use these functions to determine whether a file or directory is accessible.
They are effectively wrappers for Dir() and GetAttr() respectively.
Searching an invalid network name can be slow.

FileExists()

This function returns True if there is a file with the name you pass in, even if it is a hidden or system file.
Assumes the current directory if you do not include a path.

Returns False if the file name is a folder, unless you pass True for the second argument.
Returns False for any error, e.g. invalid file name, permission denied, server not found.

Does not search subdirectories. To enumerate files in subfolders, see List files recursively.

FolderExists()

This function returns True if the string you supply is a directory.
Return False for any error: server down, invalid file name, permission denied, and so on.

TrailingSlash()

Use the TrailingSlash() function to add a slash to the end of a path unless it is already there.

Examples

  1. Look for a file named MyFile.mdb in the Data folder:
        FileExists("C:\Data\MyFile.mdb")
  2. Look for a folder named System in the Windows folder on C: drive:
        FolderExists("C:\Windows\System")
  3. Look for a file named MyFile.txt on a network server:
        FileExists("\\MyServer\MyPath\MyFile.txt")
  4. Check for a file or folder name Wotsit on the server:
        FileExists("\\MyServer\Wotsit", True)
  5. Check the folder of the current database for a file named GetThis.xls:
        FileExists(TrailingSlash(CurrentProject.Path) & "GetThis.xls")

The code


Function FileExists(ByVal strFile As String, Optional bFindFolders As Boolean) As Boolean
    'Purpose:   Return True if the file exists, even if it is hidden.
    'Arguments: strFile: File name to look for. Current directory searched if no path included.
    '           bFindFolders. If strFile is a folder, FileExists() returns False unless this argument is True.
    'Note:      Does not look inside subdirectories for the file.
    'Author:    Allen Browne. http://allenbrowne.com June, 2006.
    Dim lngAttributes As Long

    'Include read-only files, hidden files, system files.
    lngAttributes = (vbReadOnly Or vbHidden Or vbSystem)

    If bFindFolders Then
        lngAttributes = (lngAttributes Or vbDirectory) 'Include folders as well.
    Else
        'Strip any trailing slash, so Dir does not look inside the folder.
        Do While Right$(strFile, 1) = "\"
            strFile = Left$(strFile, Len(strFile) - 1)
        Loop
    End If

    'If Dir() returns something, the file exists.
    On Error Resume Next
    FileExists = (Len(Dir(strFile, lngAttributes)) > 0)
End Function

Function FolderExists(strPath As String) As Boolean
    On Error Resume Next
    FolderExists = ((GetAttr(strPath) And vbDirectory) = vbDirectory)
End Function

Function TrailingSlash(varIn As Variant) As String
    If Len(varIn) > 0 Then
        If Right(varIn, 1) = "\" Then
            TrailingSlash = varIn
        Else
            TrailingSlash = varIn & "\"
        End If
    End If
End Function

HomeIndex of tipsTop

Rate this article:   Your rating: Poor Your rating: Not so good Your rating: Average Your rating: Good Your rating: Excellent


This is a cached tutorial, reproduced with permission.

Have your say - comment on this article.

What did you think of 'FileExists() and FolderExists()'?

No comments yet.

Why not be the first to comment on this article?!

Have your say...

Name
E-mail (e-mail address will be kept private)
Comments
Verify Code
Verification Code


It may take 30 seconds after clicking submit - please be patient to avoid duplicate submissions.  

All comments must be approved before being displayed on this web page.  This process may take up to 24 hours.